ARDUINO.CC
Go Back
Legacy Documentation
Home / Hardware / Legacy Documentation / WiFi Web Server
Note: this page refers to a product that is retired.

WiFi Web Server

Serve a webpage from the WiFi shield with Analog Input values.

Last revision 01/16/2024

In this example, you will use your WiFi Shield and your Arduino board to create a simple Web server. Using the WiFi library, your device will be able to answer a HTTP request with your WiFI shield. After opening a browser and navigating to your WiFi shield's IP address, your board will respond with just enough HTML for a browser to display the input values from all six analog pins.

This example is written for a network using WPA encryption. For WEP or WPA, change the Wifi.begin() call accordingly.

Hardware Required

  • Arduino WiFi Shield

  • Shield-compatible Arduino board

  • (optional) Six analog sensors attached to Analog Pins 0-5

Circuit

The WiFi shield uses pins 10, 11, 12, and 13 for the SPI connection to the HDG104 module. Digital pin 4 is used to control the chip select pin on the SD card.

You should have access to a 802.11b/g wireless network that connects to the internet for this example. You will need to change the network settings in the sketch to correspond to your particular networks SSID.

For networks using WPA/WPA2 Personal encryption, you need the SSID and password. The shield will not connect to networks using WPA2 Enterprise encryption.

WEP network passwords are hexadecimal strings known as keys. A WEP network can have 4 different keys; each key is assigned a "Key Index" value. For WEP encrypted networks, you need the SSID, the key, and key number.

WiFiShield bb

image developed using Fritzing. For more circuit examples, see the Fritzing project page

In the above image, the Arduino board would be stacked below the WiFi shield.

Warning

This example doesn't require an SD card. If an SD card is inserted but not used, it is possible for the sketch to hang, because pin 4 is used as SS (active low) of the SD and when not used it is configured as INPUT by default. Two possible solutions:

  • remove the SD card;

  • add these lines of code in the setup()

1pinMode(4, OUTPUT);
2digitalWrite(4, HIGH);

Code

1/*
2

3  WiFi Web Server
4

5 A simple web server that shows the value of the analog input pins.
6

7 using a WiFi shield.
8

9 This example is written for a network using WPA encryption. For
10

11 WEP or WPA, change the Wifi.begin() call accordingly.
12

13 Circuit:
14

15 * WiFi shield attached
16

17 * Analog inputs attached to pins A0 through A5 (optional)
18

19 created 13 July 2010
20

21 by dlf (Metodo2 srl)
22

23 modified 31 May 2012
24

25 by Tom Igoe
26

27 */
28

29#include <SPI.h>
30#include <WiFi.h>
31

32char ssid[] = "yourNetwork";      // your network SSID (name)
33char pass[] = "secretPassword";   // your network password
34int keyIndex = 0;                 // your network key Index number (needed only for WEP)
35

36int status = WL_IDLE_STATUS;
37

38WiFiServer server(80);
39

40void setup() {
41

42  //Initialize serial and wait for port to open:
43

44  Serial.begin(9600);
45

46  while (!Serial) {
47

48    ; // wait for serial port to connect. Needed for native USB port only
49

50  }
51

52  // check for the presence of the shield:
53

54  if (WiFi.status() == WL_NO_SHIELD) {
55

56    Serial.println("WiFi shield not present");
57

58    // don't continue:
59

60    while (true);
61

62  }
63

64  String fv = WiFi.firmwareVersion();
65

66  if (fv != "1.1.0") {
67

68    Serial.println("Please upgrade the firmware");
69

70  }
71

72  // attempt to connect to Wifi network:
73

74  while (status != WL_CONNECTED) {
75

76    Serial.print("Attempting to connect to SSID: ");
77

78    Serial.println(ssid);
79

80    // Connect to WPA/WPA2 network. Change this line if using open or WEP network:
81

82    status = WiFi.begin(ssid, pass);
83

84    // wait 10 seconds for connection:
85

86    delay(10000);
87

88  }
89

90  server.begin();
91

92  // you're connected now, so print out the status:
93

94  printWifiStatus();
95}
96

97void loop() {
98

99  // listen for incoming clients
100

101  WiFiClient client = server.available();
102

103  if (client) {
104

105    Serial.println("new client");
106

107    // an http request ends with a blank line
108

109    bool currentLineIsBlank = true;
110

111    while (client.connected()) {
112

113      if (client.available()) {
114

115        char c = client.read();
116

117        Serial.write(c);
118

119        // if you've gotten to the end of the line (received a newline
120

121        // character) and the line is blank, the http request has ended,
122

123        // so you can send a reply
124

125        if (c == '\n' && currentLineIsBlank) {
126

127          // send a standard http response header
128

129          client.println("HTTP/1.1 200 OK");
130

131          client.println("Content-Type: text/html");
132

133          client.println("Connection: close");  // the connection will be closed after completion of the response
134

135          client.println("Refresh: 5");  // refresh the page automatically every 5 sec
136

137          client.println();
138

139          client.println("<!DOCTYPE HTML>");
140

141          client.println("<html>");
142

143          // output the value of each analog input pin
144

145          for (int analogChannel = 0; analogChannel < 6; analogChannel++) {
146

147            int sensorReading = analogRead(analogChannel);
148

149            client.print("analog input ");
150

151            client.print(analogChannel);
152

153            client.print(" is ");
154

155            client.print(sensorReading);
156

157            client.println("<br />");
158

159          }
160

161          client.println("</html>");
162

163          break;
164

165        }
166

167        if (c == '\n') {
168

169          // you're starting a new line
170

171          currentLineIsBlank = true;
172

173        } else if (c != '\r') {
174

175          // you've gotten a character on the current line
176

177          currentLineIsBlank = false;
178

179        }
180

181      }
182

183    }
184

185    // give the web browser time to receive the data
186

187    delay(1);
188

189    // close the connection:
190

191    client.stop();
192

193    Serial.println("client disconnected");
194

195  }
196}
197

198void printWifiStatus() {
199

200  // print the SSID of the network you're attached to:
201

202  Serial.print("SSID: ");
203

204  Serial.println(WiFi.SSID());
205

206  // print your WiFi shield's IP address:
207

208  IPAddress ip = WiFi.localIP();
209

210  Serial.print("IP Address: ");
211

212  Serial.println(ip);
213

214  // print the received signal strength:
215

216  long rssi = WiFi.RSSI();
217

218  Serial.print("signal strength (RSSI):");
219

220  Serial.print(rssi);
221

222  Serial.println(" dBm");
223}

Last revision 2018/08/23 by SM

Suggest changes

The content on docs.arduino.cc is facilitated through a public GitHub repository. If you see anything wrong, you can edit this page here.

Need support?

Help CenterAsk the Arduino ForumDiscover Arduino Discord

License

The Arduino documentation is licensed under the Creative Commons Attribution-Share Alike 4.0 license.

ON THIS PAGE